Databases - Producing images in a Delphi Web Server

On a web page, images are included via the img tag.

Obviously, for this to work, your web server must

Create an image
Save it as a jpeg file
Add an img tag to the returned web page

Adding a graphic

This code automatically generates a jpeg file which is displayed in the web page.

The basic idea is to

Create a bitmap in memory
Copy the bitmap to a JpegImage component
Save the jpeg to the hard drive

This example plots a graph

Reads the data from a database blob
Converts the blob to an arrary
Plots the data on the bitmap

procedure TWebModule1.PlotSpectra();
var
  i          : integer                 ;
  ar         : array[0..315] of single ;
  xx         : TMemoryStream           ;
  image1     : TBitMap                 ;
  JPEG_image : TJpegImage              ;
begin

  xx            := TMemoryStream.Create;
  image1        := TBitMap.create;
  image1.Height := 200;
  image1.Width  := 400;
  JPEG_image    := TJpegImage.Create ;

  try
      // Read the data and place it in an array
    (IBTable2.FieldByName('SPECTRUM_Y') as TBlobField).SaveToStream(xx) ;  // read a blob
    xx.Position := 0;
    xx.Read(ar, 316*4);

     // Draw the plot
    image1.Canvas.FillRect(Rect(0,0,image1.Width, image1.Height));
    Image1.Canvas.MoveTo(0, 0);
    for i := 0 to 315 do begin
      Image1.Canvas.LineTo(i, trunc(ar[i] * image1.Height/50));
    end;

     // Save the jpeg file
    JPEG_image.Assign(Image1) ;
    JPEG_image.SaveToFile('Image_Path/spectra.jpeg');

  finally
     // if you create it, you must free it
    image1.Free ;
    JPEG_image.Free ;
    xx.Free ;
  end; // try

end;

This displays the spectra

procedure TWebModule1.WebModule1WebActionItem2Action(Sender: TObject; Request: TWebRequest; Response: TWebResponse; var Handled: Boolean); begin PlotSpectra; Response.Content := 'test spectra <p>' + '<img src="/Image_Path/spectra.jpeg" border=1 height=200 width=400 alt="Spectra data"> '; end;

In this example, only a single filename is used over and over. In reality, this won't work ... the new data will never be seen because the first image is stored in a cache and only the cached copy will be displayed. In the real code, each image is given a unique filename - then additional code is necessary to delete images which are over 2 hours old.

Image_Path

All the images created by a web server should be placed in a directory used for no other purpose.

It makes it easier to delete old images
You should never mix dynamically generated data with programs or static html files

In some cases, it makes since to create a special alias for that directory. Therefore, this physical directory

C:\Inetpub\wwwroot\images\spectra.jpeg

would be accessed as

http://hostname/Image_Path/spectra.jpeg

Author: Robert Clemenzi - clemenzi@cpcug.org